home *** CD-ROM | disk | FTP | other *** search
/ Commodore Disc 2 / Commodore_Disc_02_19xx_-_de.d64 / sechs verliert64 (.txt) < prev    next >
Commodore BASIC  |  2022-10-26  |  6KB  |  239 lines
  1. 10 rem sechs verliert   =========64
  2. 20 rem (c)      commodore welt    =
  3. 30 rem ============================
  4. 40 rem (p)       reginald scholz  =
  5. 50 rem                            =
  6. 60 rem                            =
  7. 70 rem                            =
  8. 80 rem c-64 + 1530/1541           =
  9. 90 rem ============================
  10. 100 poke53280,2:poke53281,2
  11. 110 wh$=chr$(5):c4$=chr$(17)
  12. 120 rn$=chr$(18):he$=chr$(19)
  13. 130 re$=chr$(28):c3$=chr$(29)
  14. 140 gr$=chr$(30):bl$=chr$(31)
  15. 150 s1$=chr$(32):bk$=chr$(144)
  16. 160 c2$=chr$(145):rf$=chr$(146)
  17. 170 cl$=chr$(147):pu$=chr$(156)
  18. 180 c1$=chr$(157):ye$=chr$(158)
  19. 190 z1$=chr$(96):z2$=chr$(98)
  20. 200 zc$=chr$(183):zd$=chr$(113)
  21. 210 forq=1to40:q1$=q1$+z1$:next
  22. 220 forq=1to13:q2$=q2$+z1$:next
  23. 230 forq=1to11:q3$=q3$+c3$:next
  24. 240 forq=1to29:s$=s$+s1$:next
  25. 250 c$=he$
  26. 260 forq=1to23:c$=c$+c4$:next
  27. 270 forq=1to5:c$=c$+c3$:next
  28. 280 forq=1to10:tt$=tt$+s1$:next
  29. 290 k$="nichts geht mehr !    "+tt$+s1$
  30. 300 ss=0:cs=0
  31. 310 gosub1240
  32. 320 printcl$bk$left$(q1$,39)
  33. 330 printye$" das superwuerfelspiel"
  34. 340 printbk$left$(q1$,39)
  35. 350 printc4$wh$" kennen sie die spielregeln bereits ?"
  36. 360 printc4$" (j/n)"
  37. 370 poke198,0:wait198,1:geta$
  38. 380 ifa$="n"thengosub2030
  39. 390 gosub1060
  40. 400 printc$;:input" ihr name bitte ";n$
  41. 410 iflen(n$)>8thenprintc2$c2$"maximal 8 buchstaben !    ":printc$s$:goto400
  42. 420 gosub1060
  43. 430 t1=0:t2=0:z1=0:z2=0
  44. 440 ff=int(rnd(1)*2+1)
  45. 450 ifff=1then600
  46. 460 printc$s$
  47. 470 printc$;"'taste'  =  wuerfeln          "
  48. 480 poke198,0:wait198,1:geta$
  49. 490 ifa$<>" "then480
  50. 500 gosub1750:gosub1450:gosub1830
  51. 510 ifw1=6orw2=6thenprintc$s$c$k$:goto580
  52. 520 printc$;"'taste' = wuerfeln  'h' = halten"
  53. 530 poke198,0:wait198,1:geta$
  54. 540 ifa$=" "then500
  55. 550 ifa$<>"h"then530
  56. 560 printc$s$c$n$;tab(14);"haelt "z2" punkte !      "
  57. 570 t2=t2+z2:ift2>99then730
  58. 580 z2=0:gosub1610
  59. 590 fori=1to2000:next
  60. 600 ff=1:printc$s$
  61. 610 printc$"computer wuerfelt !  "tt$
  62. 620 fori=1to1000:next
  63. 630 gosub1750:gosub1450:gosub1830
  64. 640 if w1=6orw2=6thenprintc$s$c$k$:goto690
  65. 650 gosub1910
  66. 660 if jn=1then610
  67. 670 printc$s$c$;"computer haelt"z1"punkte"tt$:fori=1to2000:next
  68. 680 t1=t1+z1
  69. 690 z1=0:gosub1610
  70. 700 if t1>99then800
  71. 710 ff=2
  72. 720 goto460
  73. 730 rem ***************************
  74. 740 rem *********** spieler siegt *
  75. 750 rem ***************************
  76. 760 printc$s$c$c1$c1$c1$c1$c1$n$" hat mit"t2":"t1" gewonnen"
  77. 770 ss=ss+1
  78. 780 fori=1to3000:next
  79. 790 goto900
  80. 800 rem ***************************
  81. 810 rem ********** computer siegt *
  82. 820 rem ***************************
  83. 830 printc$s$c$c1$c1$c1$c1$c1$"computer hat mit"t1":"t2" gewonnen"
  84. 840 cs=cs+1
  85. 850 fori=1to3000:next
  86. 860 rem ***************************
  87. 870 rem ************* gesamtstand *
  88. 880 rem ***************************
  89. 890 gosub1060
  90. 900 printleft$(c$,7);
  91. 910 printtab(13);rn$ye$" gesamtstand "
  92. 920 printtab(13);rn$ye$q2$
  93. 930 printtab(13);rn$ye$tt$left$(s$,3)
  94. 940 printtab(13);rn$ye$c2$s1$n$;tab(23);str$(ss)
  95. 950 printtab(13);rn$ye$q2$
  96. 960 printtab(13);rn$ye$tt$left$(s$,3)
  97. 970 printtab(13);rn$ye$c2$" cbm-64"tab(23);str$(cs)
  98. 980 printc$s$c$" "rn$"nochmal ?"
  99. 990 poke198,0:wait198,1:geta$
  100. 1000 ifa$="j"then420
  101. 1010 ifa$<>"n"then990
  102. 1020 end
  103. 1030 rem ***************************
  104. 1040 rem ************** bildaufbau *
  105. 1050 rem ***************************
  106. 1060 printcl$:poke53280,6:poke53281,6
  107. 1070 printc4$q3$rn$wh$zc$left$(s$,16)zc$
  108. 1080 printleft$(q3$,9)rn$zc$"    sechs verliert  "zc$
  109. 1090 printleft$(q3$,7)rn$zc$left$(s$,24)zc$
  110. 1100 fori=1to9
  111. 1110 printtab(10);rn$z2$rf$;tab(29);rn$z2$rf$
  112. 1120 next
  113. 1130 printleft$(q3$,9)rn$left$(s$,8)" wurf  total"left$(s$,2)
  114. 1140 printleft$(q3$,8)rn$left$(s$,24)
  115. 1150 printleft$(q3$,7)rn$s1$" cbm-64    0      0"left$(s$,6)
  116. 1160 printleft$(q3$,5)rn$s$s1$
  117. 1170 printleft$(q3$,3)rn$left$(s$,16)"0      0"left$(s$,10)
  118. 1180 printc3$rn$s$left$(s$,9)
  119. 1190 printc2$c2$rn$;tab(15-len(n$));n$
  120. 1200 return
  121. 1210 rem **************************
  122. 1220 rem ****** wuerfeldefinition *
  123. 1230 rem **************************
  124. 1240 dim w$(6,5)
  125. 1250 w1$=rn$+wh$+s1$+s1$+zd$+s1$+s1$
  126. 1260 w2$=rn$+wh$+zd$+left$(s$,4)
  127. 1270 w3$=rn$+wh$+zd$+left$(s$,3)+zd$
  128. 1280 w4$=rn$+wh$+zd$+s1$+zd$+s1$+zd$
  129. 1290 w5$=rn$+wh$+left$(s$,4)+zd$
  130. 1300 fori=1to6
  131. 1310 forj=1to5
  132. 1320 w$(i,j)=rn$+wh$+left$(s$,5)
  133. 1330 nextj
  134. 1340 nexti
  135. 1350 w$(1,3)=w1$
  136. 1360 w$(2,1)=w2$:w$(2,5)=w5$
  137. 1370 w$(3,1)=w2$:w$(3,3)=w1$:w$(3,5)=w5$
  138. 1380 w$(4,1)=w3$:w$(4,5)=w3$
  139. 1390 w$(5,1)=w3$:w$(5,3)=w1$:w$(5,5)=w3$
  140. 1400 w$(6,1)=w4$:w$(6,5)=w4$
  141. 1410 return
  142. 1420 rem **************************
  143. 1430 rem ******* wuerfel zeichnen *
  144. 1440 rem **************************
  145. 1450 printleft$(c$,7);
  146. 1460 fori=1to5
  147. 1470 printtab(13)left$(s$,14)
  148. 1480 next
  149. 1490 printleft$(c$,7)
  150. 1500 fori=1to5
  151. 1510 printtab(14)w$(w1,i)
  152. 1520 next
  153. 1530 printleft$(c$,7)
  154. 1540 fori=1to5
  155. 1550 printtab(21)w$(w2,i)
  156. 1560 next
  157. 1570 return
  158. 1580 rem **************************
  159. 1590 rem ************** protokoll *
  160. 1600 rem **************************
  161. 1610 ifff=2then1670
  162. 1620 z$=str$(z1):z$=right$(z$,len(z$)-1)
  163. 1630 t$=str$(t1):t$=right$(t$,len(t$)-1)
  164. 1640 printleft$(c$,17)rn$tab(16)left$(s$,17)
  165. 1650 printleft$(c$,17)rn$tab(20-len(z$));z$;tab(27-len(t$));t$
  166. 1660 goto1710
  167. 1670 z$=str$(z2):z$=right$(z$,len(z$)-1)
  168. 1680 t$=str$(t2):t$=right$(t$,len(t$)-1)
  169. 1690 printleft$(c$,19)rn$tab(16)left$(s$,17)
  170. 1700 printleft$(c$,19)rn$tab(20-len(z$));z$;tab(27-len(t$));t$
  171. 1710 return
  172. 1720 rem **************************
  173. 1730 rem *************** wuerfeln *
  174. 1740 rem **************************
  175. 1750 fori=1to20:printleft$(c$,10)tab(13)ye$"w u e r f e l n"wh$
  176. 1760 printleft$(c$,10)tab(13)left$(s$,15):next
  177. 1770 w1=int(rnd(1)*6+1)
  178. 1780 w2=int(rnd(1)*6+1)
  179. 1790 return
  180. 1800 rem **************************
  181. 1810 rem ****** protokoll fuehren *
  182. 1820 rem **************************
  183. 1830 if ff=1then1850
  184. 1840 z2=z2+w1+w2:goto1860
  185. 1850 z1=z1+w1+w2
  186. 1860 gosub1610
  187. 1870 return
  188. 1880 rem **************************
  189. 1890 rem *********** computer-zug *
  190. 1900 rem **************************
  191. 1910 ifz1>30 thenjn=2:goto1990
  192. 1920 jn=1
  193. 1930 ifrnd(1)<.1thenjn=2:goto1990
  194. 1940 ifint(rnd(1)*(t1+t2))<6thenjn=1:goto1990
  195. 1950 if t1+z1>99thenjn=2
  196. 1960 if z1>13thenjn=2
  197. 1970 ifrnd(1)<.4then1990
  198. 1980 ifz1>7andt1-t2>10thenjn=2
  199. 1990 return
  200. 2000 rem **************************
  201. 2010 rem ************* erklaerung *
  202. 2020 rem **************************
  203. 2030 printcl$bk$left$(q1$,39)
  204. 2040 printye$" spielregeln fuer das wuerfelspiel."
  205. 2050 printbk$left$(q1$,39)
  206. 2060 printc4$wh$" >> sechs verliert << wird mit zwei"
  207. 2070 printc4$" wuerfeln gespielt. sie spielen gegen"
  208. 2080 printc4$" den computer und das ziel ist es, 100"
  209. 2090 printc4$" oder mehr punkte vor dem computer zu"
  210. 2100 printc4$" erreichen. fuer einen gluecksritter "
  211. 2110 printc4$" duerfte das kein problem sein."
  212. 2120 printc4$" spielen sie vorsichtig, der computer"
  213. 2130 printc4$" hat einige tricks drauf."
  214. 2140 printc4$" "rn$"           weiter mit space           "
  215. 2150 poke198,0:wait198,1:geta$
  216. 2160 ifa$<>" "then2150
  217. 2170 printcl$bk$left$(q1$,39)
  218. 2180 printye$" spielregeln fuer das wuerfelspiel"
  219. 2190 printbk$left$(q1$,39)
  220. 2200 printc4$wh$" wenn sie am zug sind, koennen sie so"
  221. 2210 printc4$" oft wuerfeln wie sie wollen. dabei"
  222. 2220 printc4$" wird, wenn sie die punktzahl halten"
  223. 2230 printc4$" wollen, diese punktzahl ihrem total-"
  224. 2240 printc4$" stand zugezaehlt. sollten sie aller-"
  225. 2250 printc4$" dings eine 6 wuerfeln, so verfaellt"
  226. 2260 printc4$" die gesamte punktzahl und der c-64"
  227. 2270 printc4$" ist mit seinen versuchen dran."
  228. 2280 printc4$" "rn$"           weiter mit space           "
  229. 2290 poke198,0:wait198,1:geta$
  230. 2300 ifa$<>" "then2290
  231. 2310 return
  232. 2320 rem sechs verliert   =======64
  233. 2330 rem 38911 bytes memory    ====
  234. 2340 rem 06397 bytes program   ====
  235. 2350 rem 00308 bytes variables ====
  236. 2360 rem 00135 bytes arrays    ====
  237. 2370 rem 02717 bytes strings   ====
  238. 2380 rem 30356 bytes free      ====
  239.